Configurar Fluxos de trabalho de Salesforce para Agent Workspace (Agent)

Você pode configurar os fluxos de trabalho de pesquisa, Criação Personalizada, Criação Padrão e Atualização para Salesforce e NiCE CXone Agent Workspace (Agent). Estes fluxos de trabalho pesquisam, criam ou atualizam registros de Salesforce, também chamados de objetos. Essa é a configuração de back-end do mapeamento de dados dinâmicos.

Tipo de Workflow

Descrição

Fluxos de trabalho

Procurar Fluxos de trabalho de pesquisa escaneiam Salesforce em busca de registros aplicáveis à interaçãoClosed A conversa completa com um agente por meio de um canal. Por exemplo, uma interação pode ser uma chamada de voz, um e-mail, um chat ou uma conversa em mídia social. que o agente está tratando. Pesquisar ANI
Pesquisa personalizada
Criação personalizada Os fluxos de trabalho de Criação personalizada criam qualquer tipo de registro com campos personalizados e padrão. Criar gravação personalizada
Criação padrão

Os fluxos de trabalho Criação padrão criam registros padrão do Salesforce com os campos de dados padrão. A carga útil SNIPPET desses fluxos de trabalho deve incluir os campos padrão e somente esses campos.

Criar conta
Criar Caso
Criar Contato
Criar lead
Criar Oportunidade
Criar Ordem de Serviço
Atualizar Os fluxos de trabalho de atualização atualizam os valores de campo de um registro. Eles podem ser usados para atualizar um registro recuperado por um fluxo de trabalho de Busca ou um registro criado por um fluxo de trabalho de Criação Personalizada ou Criação Padrão. Atualizar Registro

Os campos Created By e Modified By Salesforce usam o nome do usuário do sistema. Esta é a conta de usuário Salesforce que você criou especificamente para a configuração de NiCE CXone. O campo Assigned To mostra o nome do agente que está tratando a interação.

Antes de começar, revise o diagrama de integração de CRM, o diagrama de workflow de CRM e a lista de terminologia de integração de CRM.

Além disso, baixe esta pasta de scripts de modelo. Ela contém scripts de voz e digitais para NiCE CXone Studio e Desktop Studio.

Configurar Fluxos de trabalho de pesquisa

Há dois fluxos de trabalho de pesquisa: Procurar ANI e pesquisa personalizada.

O workflow de Search pode retornar somente um registro. Isso é chamado de correspondência única.

Se você quiser que o fluxo de trabalho de pesquisa retorne registros de ordem de serviço, deverá usar uma pesquisa genérica, não uma pesquisa padrão. Uma pesquisa padrão é baseada em um endereço DE e-mail ou número de telefone. Uma pesquisa genérica é baseada em qualquer campo do registro.

Quando você usa mapeamentos de dados dinâmicos em um workflow de pesquisa, a seção Interactions Relacionados no cartão do cliente icon: a person next to a document. mostra primeiro os registros que:

  • Corresponder aos critérios de busca, e

  • Ter dados em cada campo mapeado.

Os agentes podem clicar em Atualizar no cartão do cliente icon: a person next to a document. para visualizar todos os registros que correspondem aos critérios de pesquisa.

Configurar o Workflow Search for ANI

O workflow Search for ANI usa o ANIClosed Também conhecido como id do chamador. número de telefone listado de uma chamada de voz recebida. de ACD para pesquisar em todos os campos de telefone padrão por registros correspondentes.

Não inclua a propriedade timeoutMilliSec em seu código de Workflow. Isso pode fazer com que múltiplas interações iguais sejam entregues aos seus agentes.

  1. Em Studio, abra o script em que você deseja configurar o workflow Search for ANI.

  2. Se ainda não o fez, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET no canvas do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC searchInput
    searchInput.workflowInput.phoneNumber = "{ANI}"
    						
    ASSIGN searchJson = "{searchInput.asjson()}"
    
    		
  5. Salve o seu script.

  6. Você pode testar seu script simulando uma interação em Studio simulando uma interação em Studio. Corrigindo a duplicação: Você pode testar seu script simulando uma interação em Studio.

Configure o fluxo de trabalho de Procurar Personalizado

O fluxo de trabalho pesquisa Personalizada permite que você pesquise Salesforce registros que correspondam a critérios de filtragem flexíveis. Você pode usar a pesquisa Personalizada para:

  • Pesquisar um único tipo de registro de Salesforce, como Account.
  • Pesquise múltiplo tipos de registro Salesforce na mesma instância do CRM em uma única carga útil. Por exemplo, você pode pesquisar Case e Contact ao mesmo tempo.
  • Use múltiplos campos e variáveis no filtro de pesquisa.
  • Conecte condições de pesquisa com operadores Salesforce, como AND, OR, =, !=, < e >.

Você pode pesquisar qualquer combinação de até 5 registros de Salesforce em uma única carga útil. Não há limite imposto para o número de campos em uma Custom Search. No entanto, pesquisar muitos campos em uma única carga útil pode tornar a pesquisa lenta. Comece com um pequeno conjunto de campos e expanda conforme necessário.

Não inclua a propriedade timeoutMilliSec em seu código de Workflow. Isso pode fazer com que múltiplas interações iguais sejam entregues aos seus agentes.

  1. Em Studio, abra o script em que deseja configurar o workflow Custom Search.

  2. Se ainda não o fez, adicione uma ação SNIPPET depois de BEGIN e antes da ação WORKFLOW EXECUTE.

  3. Dê um duplo clique na ação SNIPPET no canvas do script.

  4. Copie um dos blocos de código de exemplo abaixo e cole-o na aba Text View da janela editor. Em seguida, atualize os valores conforme necessário.

  5. Salve o seu script.

  6. Você pode testar seu script simulando uma interação em Studio.

Opção 2: configurar uma Procurar personalizada de múltiplas entidades

Configurar Fluxos de trabalho de criação personalizados

Os fluxos de trabalho de criação personalizada permitem configurar uma carga útil de SNIPPET para criar qualquer tipo de registro de Salesforce, padrão ou personalizado. Também permite que você preencha qualquer tipo DE campo, padrão ou personalizado. Por exemplo, você pode criar um registro de Conta com alguns dos campos padrão desse tipo de registro, bem como seus próprios campos personalizados.

Esse é o método recomendado para criar registros do Salesforce.

Configurar o Fluxo de trabalho Criar registro personalizado (o antigo fluxo de trabalho Criar entidade)

O workflow Create Custom Record cria qualquer tipo de registro Salesforce, padrão ou personalizado. Esse registro pode exibir campos de dados padrão e personalizados. Os campos devem conter texto, números ou variáveis. Os campos vinculados geralmente são preenchidos por resultados da pesquisa ou listas de opções, mas você pode configurar este workflow para adicionar dados codificados de forma fixa a um campo vinculado.

Se você usar a versão mais antiga deste workflow, chamada de workflow Criar entidade, você precisa configurar seu script Studio com duas ações adicionais: um SNIPPET chamado Snippet for Send Workflow Response, e um CUSTOMEVENT chamado Send Workflow Response. Use este script de modelo para Desktop Studio ou este script de modelo para Studio.

  1. Em Studio, abra o script no qual você deseja configurar o workflow Create Custom Record.

  2. Se ainda não o fez, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET no canvas do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela do editor.

    
    DYNAMIC createPayload
    DYNAMIC createDataArray
    						
    DYNAMIC item1
    item1.key = "[API name]"
    item1.value = "[variable]"
    DYNAMIC item2
    item2.key = "[API name]"
    item2.value = "[variable]"
    DYNAMIC item3
    item3.key = "[API name]"
    item3.value = "[variable]"
    
    createPayload.entity = "[record type]"
    createDataArray[1] = item1
    createDataArray[2] = item2
    createDataArray[3] = item3
    
    createPayload.data = createDataArray
    						
    createPayload.pinnedRecord = "[true or false]"
    createPayload.screenPop = "[true or false]"
    createPayload.relatesTo = "[true or false]"						
    										
    DYNAMIC create[RecordName]Payload
    create[RecordName]Payload.workflowInput = createPayload
    						
    ASSIGN createJson = "{create[RecordName]Payload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas.

  5. Altere os valores dos atributos listados abaixo. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Modifique o valor de item1.key para o primeiro campo que deseja exibir. Modifique o item1.value para o valor desse campo. Por exemplo:

      
      item1.key = "Status"
      item1.value = "New"
      		
    2. Modifique o valor de item2.key para o segundo campo que deseja exibir. Modifique o item2.value para o valor desse campo. Por exemplo:

      
      item2.key = "Origin"
      item2.value = "Phone"
      		
    3. Modifique o valor de item3.key para o terceiro campo que deseja exibir. Modifique o item3.value para o valor desse campo. Por exemplo:

      
      item3.key = "CXone_Contact_ID_c"
      item3.value = "{ContactID}"
      		
  6. Para adicionar campos adicionais:

    1. Crie outros item objetos de dados dinâmicos após item3.value. Seguir este formato:

      
      DYNAMIC item#
      item#.key = "[Field #]"
      item#.value = "[Field # Value]"
      		

      O número (#) precisa incrementar em um a cada objeto de dados dinâmicos adicional que você adicionar. Por exemplo: item4, item5 e assim por diante.

    2. Crie outras matrizes de dados após createDataArray[3]. Siga esse formato:

      
      ASSIGN createDataArray[#] = item#
      		

      O número (#) precisa ser incrementado em um a cada item adicional que você adicionar à matriz. Por exemplo: createDataArray[4], createDataArray[5] e assim por diante.

  7. Altere o valor do atributo createPayload.entity para o nome de API do registro que você deseja usar. Por exemplo, createPayload.entity = "account". Isso diferencia maiúsculas de minúsculas.

    Para localizar o nome da API do registro, abra Salesforce e navegue até Setup Icon of gray gear with a lightning bolt in the center > Object Manager. Clique no nome do registro. Na página Detalhes que é aberta, localize o Nome da API.

  8. Altere o valor do atributo createPayload.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Atual Interactions do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir este atributo na carga útil, ele será considerado como false.
  9. Altere o valor do atributo createPayload.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir este atributo na carga útil, ele será considerado como false.
  10. Altere o valor do atributo createPayload.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  11. Altere todas as instâncias do [RecordName] nas últimas três linhas do código para o nome do registro que você criou. Capitalize o nome para corresponder ao camel case do atributo. Por exemplo, se o nome do registro que você criou for workorder, seu código será:

    
    DYNAMIC createWorkOrderPayload
    createWorkOrderPayload.workflowInput = createPayload
    						
    ASSIGN createJson = "{createWorkOrderPayload.asjson()}"
    		
  12. Salve o seu script.

  13. Você pode testar seu script simulando uma interação no Studio.

Configurar Fluxos de trabalho de criação Padrão

Fluxos de trabalho de criação padrão criam registros Salesforce padrão com os campos especificados na carga útil do fluxo de trabalho.

Você não pode adicionar ou excluir campos na carga útil SNIPPET dos fluxos de trabalho Criação Padrão. Se você adicionar ou excluir campos, o fluxo de trabalho falhará e o registro não será criado. Para criar um registro padrão ou personalizado com os campos desejados, use o workflow Create Custom Record.

Configurar o Workflow de Criar conta

  1. Em Studio, abra o script em que você deseja configurar o workflow Create Account.

  2. Caso ainda não tenha feito isso, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Dê duplo clique na ação SNIPPET na tela do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createAccount
    createAccount.accountName = "[account name]"
    createAccount.accountType = "[account type]"
    createAccount.accountPhone = "{ANI}"
    						
    createAccount.pinnedRecord = "[true or false]"
    createAccount.screenPop = "[true or false]"
    createAccount.relatesTo = "[true or false]"	
    						
    DYNAMIC createAccountPayload
    createAccountPayload.workflowInput = createAccount
    
    ASSIGN createAccountJson = "{createAccountPayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se quiser que um campo permaneça em branco, você pode usar um valor nulo (""). Por exemplo, createAccount.accountType = "". Contudo, não é possível atribuir um valor nulo para createAccount.accountName.

  5. Altere o valor do atributo createAccount.accountName para o nome da conta. Por exemplo, createAccount.accountName = "Elinor from Classics, Inc.". Este valor pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável se quiser que este valor seja atualizado a cada interação.

  6. Altere o valor do atributo createAccount.accountType para o tipo de conta. Por exemplo, createAccount.accountType = "Book Orders - Chat". Este valor pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável se quiser que este valor seja atualizado a cada interação.

  7. Altere o valor do atributo createAccount.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Interactions atual do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createAccount.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  9. Altere o valor do atributo createAccount.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  10. Clique na ação Execução do fluxo de trabalho que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createAccountJson}. Certifique-se de incluir as chaves.

  11. Salve seu script.

  12. Você pode testar seu script simulando uma interação no Studio.

Configurar o Workflow Criar Caso

  1. Em Studio, abra o script em que deseja configurar o workflow Create Case.

  2. Caso ainda não tenha feito isso, adicione uma ação SNIPPET depois de BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET na tela do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createCase
    createCase.entityType = "[Contact or Account]"
    createCase.name = "[case name]"
    createCase.phone = "{ANI}"
    createCase.email = "[case email]"
    createCase.company = "[case company]"
    createCase.status = "[case status]"
    createCase.caseReason = "[reason for case]"
    createCase.caseOrigin = "{SKILL}"
    createCase.priority = "[low, medium, high, or critical]"
    createCase.description = "New Record - {CONTACTID}"
    createCase.internalComments = "[internal comments]"
    						
    createCase.pinnedRecord = "[true or false]"
    createCase.screenPop = "[true or false]"
    createCase.relatesTo = "[true or false]"	
    						
    DYNAMIC createCasePayload
    createCasePayload.workflowInput = createCase
    
    ASSIGN createCaseJson = "{createCasePayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se você quiser que um campo permaneça em branco, pode usar um valor nulo (""). Por exemplo, createCase.name = "". Contudo, não é possível atribuir um valor nulo para createCase.entityType ou createCase.status.

  5. Altere os valores dos atributos. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Altere o valor do atributo createCase.entityType para Contact ou Account. Por exemplo, createCase.entityType = "Contact".

    2. Altere o valor do atributo createCase.name para o nome do caso. Por exemplo, createCase.name = "Elinor Dashwood's Case".

    3. Altere o valor do atributo createCase.email para o endereço DE e-mail do caso. Por exemplo, createCase.email = "elinor.dashwood@classics.com".

    4. Altere o valor do atributo createCase.company para a organização do caso. Por exemplo, createCase.company = "Classics, Inc.".

    5. Altere o valor do atributo createCase.status para o status do caso. Por exemplo, createCase.status = "New".

    6. Altere o valor do atributo createCase.caseReason para o motivo do caso. Por exemplo, createCase.caseReason = "Shipping problems".

    7. Altere o valor do atributo createCase.priority para low, medium, high ou critical. Por exemplo, createCase.priority = "low".

    8. Altere o valor do atributo createCase.internalComments para uma descrição do caso para uso interno. Por exemplo, createCase.internalComments = "Elinor's book order is missing. It might have a wrong shipping address.".

  6. Altere o valor do atributo createCase.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Interactions atual do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, será assumido como false.
  7. Altere o valor do atributo createCase.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createCase.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir este atributo na carga útil, será considerado como false.
  9. Clique na ação Workflow Execute que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createCaseJson}. Certifique-se de incluir as chaves.

  10. Salve o seu script.

  11. Você pode testar seu script simulando uma interação no Studio.

Configure o Workflow de Criação de Contato

  1. Em Studio, abra o script no qual você deseja configurar o workflow Create Contact.

  2. Se ainda não o fez, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET no canvas do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createContact
    createContact.firstName = "[first name]"
    createContact.lastName = "[last name]"
    createContact.homePhone = "{ANI}"
    createContact.mobilePhone = "[mobile phone number]"
    createContact.businessPhone = "{ANI}"
    createContact.email = "[email address]"
    createContact.contactDescription = "[description of contact]"
    						
    createContact.pinnedRecord = "[true or false]"
    createContact.screenPop = "[true or false]"
    createContact.relatesTo = "[true or false]"	
    
    DYNAMIC createContactPayload
    createContactPayload.workflowInput = createContact
    
    ASSIGN createContactJson = "{createContactPayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se quiser que um campo permaneça em branco, você pode usar um valor nulo (""). Por exemplo, createContact.firstName = "". Contudo, não é possível atribuir um valor nulo para createContact.lastName.

  5. Altere os valores dos atributos. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Altere o valor do atributo createContact.firstName para o nome próprio do contato. Por exemplo, createContact.firstName = "Elinor".

    2. Altere o valor do atributo createContact.lastName para o sobrenome do contato. Por exemplo, createContact.lastName = "Dashwood".

    3. Altere o valor do atributo createContact.mobilePhone para o número de telefone celular do contato. Por exemplo, createContact.mobilePhone = "1234567890".

    4. Altere o valor do atributo createContact.email para o endereço DE e-mail do contato. Por exemplo, createContact.email = "elinor.dashwood@classics.com".

    5. Altere o valor do atributo createContact.contactDescription para uma descrição do contato. Por exemplo, createContact.contactDescription = "Elinor needs help with her book order".

  6. Altere o valor do atributo createContact.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido para os agentes na seção Interactions atual do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  7. Altere o valor do atributo createContact.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createContact.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  9. Clique na ação Execução do fluxo de trabalho que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createContactJson}. Certifique-se de incluir as chaves.

  10. Salve o seu script.

  11. Você pode testar seu script simulando uma interação no Studio.

Configure the Create Lead Workflow

  1. Em Studio, abra o script no qual você deseja configurar o workflow Create Lead.

  2. Se ainda não o fez, adicione uma ação SNIPPET depois de BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET na tela do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createLead
    createLead.firstName = "[first name]"
    createLead.lastName = "[last name]"
    createLead.company = "[company]"
    createLead.phone = "{ANI}"
    createLead.email = "[email address]"
    createLead.website = "[website URL]"
    createLead.description = "New Record - {CONTACTID}"
    createLead.status = "[status of lead]"
    						
    createLead.pinnedRecord = "[true or false]"
    createLead.screenPop = "[true or false]"
    createLead.relatesTo = "[true or false]"	
    						
    DYNAMIC createLeadPayload
    createLeadPayload.workflowInput = createLead
    
    ASSIGN createLeadJson = "{createLeadPayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se quiser que um campo permaneça em branco, você pode usar um valor nulo (""). Por exemplo, createLead.firstName = "". Contudo, não é possível atribuir um valor nulo para createLead.lastName, createLead.company ou createLead.status.

  5. Altere os valores dos atributos. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Altere o valor do atributo createLead.firstName para o nome próprio do lead. Por exemplo, createLead.firstName = "Elinor".

    2. Altere o valor do atributo createLead.lastName para o sobrenome do lead. Por exemplo, createLead.lastName = "Dashwood".

    3. Altere o valor do atributo createLead.company para a organização do lead. Por exemplo, createLead.company = "Classics, Inc.".

    4. Altere o valor do atributo createLead.email para o endereço DE e-mail do lead. Por exemplo, createLead.email = "elinor.dashwood@classics.com".

    5. Altere o valor do atributo createLead.website para o site do lead. Por exemplo, createLead.website = "classics.com".

    6. Altere o valor do atributo createLead.status para o status do lead. Por exemplo, createLead.status = "New".

  6. Altere o valor do atributo createLead.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Interactions atual do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, será considerado como false.
  7. Altere o valor do atributo createLead.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createLead.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  9. Clique na ação Workflow Execute que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createLeadJson}. Certifique-se de incluir as chaves.

  10. Salve o seu script.

  11. Você pode testar seu script simulando uma interação no Studio.

Configure o Workflow de criação de oportunidade

  1. Em Studio, abra o script no qual você deseja configurar o workflow Criar Oportunidade.

  2. Se ainda não o fez, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET na tela do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createOpportunity
    createOpportunity.name = "[opportunity name]"
    createOpportunity.description = "New Record - {CONTACTID}"
    createOpportunity.stageName = "[stage of opportunity]"
    createOpportunity.closeDate = "[YYYY-MM-DD]"
    						
    createOpportunity.pinnedRecord = "[true or false]"
    createOpportunity.screenPop = "[true or false]"
    createOpportunity.relatesTo = "[true or false]"	
    						
    DYNAMIC createOpportunityPayload
    createOpportunityPayload.workflowInput = createOpportunity
    
    ASSIGN createOpportunityJson = "{createOpportunityPayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se quiser que um campo permaneça em branco, você pode usar um valor nulo (""). Por exemplo, createOpportunity.description = "". Contudo, não é possível atribuir um valor nulo para createOpportunity.name, createOpportunity.stageName ou createOpportunity.closeDate.

  5. Altere os valores dos atributos. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Altere o valor do atributo createOpportunity.name para o nome da oportunidade. Por exemplo, createOpportunity.name = "Classics, Inc. Elinor".

    2. Altere o valor do atributo createOpportunity.stageName para o estágio da oportunidade. Por exemplo, createOpportunity.stageName = "New".

    3. Altere o valor do atributo createOpportunity.closeDate para a data em que a oportunidade foi fechada. Por exemplo, createOpportunity.closeDate = "2024-01-31".

  6. Altere o valor do atributo createOpportunity.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Interactions atual do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, será assumido como false.
  7. Altere o valor do atributo createOpportunity.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createOpportunity.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir este atributo na carga útil, será considerado como false.
  9. Clique na ação Execução do fluxo de trabalho que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createOpportunityJson}. Certifique-se de incluir as chaves.

  10. Salve o seu script.

  11. Você pode testar seu script simulando uma interação em Studio simulando uma interação em Studio. Desculpe, segue a versão corrigida: Você pode testar seu script simulando uma interação em Studio.

Configurar o Fluxo de trabalho de criação de ordem de serviço

  1. Em Studio, abra o script no qual deseja configurar o workflow Criar Ordem de Trabalho.

  2. Se ainda não o fez, adicione uma ação SNIPPET após BEGIN e antes da ação Execução do fluxo de trabalho.

  3. Duplo clique na ação SNIPPET no canvas do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    DYNAMIC createWorkOrder
    createWorkOrder.description = "New Record - {CONTACTID}"
    createWorkOrder.startDate = "[YYYY-MM-DD]"
    createWorkOrder.endDate = "[YYYY-MM-DD]"
    createWorkOrder.subject = "New Record"
    createWorkOrder.status = "[status]"
    createWorkOrder.priority = "[low, medium, high, or critical]"
    createWorkOrder.duration = "[number of minutes or hours]"
    						
    createWorkOrder.pinnedRecord = "[true or false]"
    createWorkOrder.screenPop = "[true or false]"
    createWorkOrder.relatesTo = "[true or false]"	
    
    DYNAMIC createWorkOrderPayload
    createWorkOrderPayload.workflowInput = createWorkOrder
    
    ASSIGN createWorkOrderJson = "{createWorkOrderPayload.asjson()}"
    		

    É necessário incluir cada uma dessas linhas. Se desejar que um campo permaneça em branco, você pode usar um valor nulo (""). Por exemplo, createWorkOrder.description = "".

  5. Altere os valores dos atributos. Qualquer um destes pode ser codificado, uma variável ou uma combinação destes. Utilize uma variável, caso queira que o valor seja atualizado a cada interação.

    1. Altere o valor do atributo createWorkOrder.startDate para a data em que a ordem de serviço foi iniciada. Por exemplo, createWorkOrder.startDate = "2024-01-30".

    2. Altere o valor do atributo createWorkOrder.endDate para a data em que a ordem de serviço terminou. Por exemplo, createWorkOrder.endDate = "2024-01-31".

    3. Altere o valor do atributo createWorkOrder.status para o status do pedido de trabalho. Por exemplo, createWorkOrder.status = "New".

    4. Altere o valor do atributo createWorkOrder.priority para low, medium, high ou critical. Por exemplo, createWorkOrder.priority = "low".

    5. Altere o valor do atributo createWorkOrder.duration para o número de minutos ou horas que levou para concluir a ordem de serviço. Por exemplo, createWorkOrder.duration = "02".

  6. Altere o valor do atributo createWorkOrder.pinnedRecord para true ou false. Quando definido como true, o registro criado é exibido aos agentes na seção Interactions atuais do cartão do cliente. Quando definido como false, ele é exibido na seção Interações recentes do cartão do cliente. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  7. Altere o valor do atributo createWorkOrder.screenPop para true ou false. Quando definido como true, o registro criado aparece automaticamente para o agente como um pop-up de tela no Salesforce. Quando definido como false, isso não acontece. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  8. Altere o valor do atributo createWorkOrder.relatesTo para true ou false. Quando definido como true, os agentes podem relacionar registros manualmente dentro de Agent Workspace (Agent). Quando definido como false, eles não podem; a relação dos registros acontece automaticamente por meio da memorização dos dados. Se você não incluir esse atributo na carga útil, ele será considerado como false.
  9. Clique na ação Workflow Execute que vem depois do SNIPPET deste Fluxo de trabalho. Altere a propriedade workflowPayload dessa ação para {createWorkOrderJson}. Certifique-se de incluir as chaves.

  10. Salve o seu script.

  11. Você pode testar seu script simulando uma interação no Studio.

Atualizar Fluxos de trabalho

Os fluxos de trabalho de atualização permitem que você configure uma carga útil de SNIPPET para atualizar qualquer tipo de registro Salesforce, padrão ou personalizado. Os fluxos de trabalho de atualização podem atualizar registros recuperados por fluxos de trabalho de pesquisa. Eles também podem atualizar registros criados por fluxos de trabalho de criação personalizada e criação Padrão.

Elinor Dashwood configura fluxos de trabalho de criação personalizados para criar registros antes que as interações sejam atribuídas aos agentes. Dessa forma, os registros estão prontos para aparecer sem retardo. No entanto, eles não contêm as informações do agente que atendeu. Ela configura um fluxo de trabalho de atualização para adicionar essas informações após a atribuição do agente.

Configure o Workflow Atualizar Registro

A Update Record workflow atualiza os campos em um registro. Você pode usá-lo para:

  • Atualize os campos de um registro recuperado por um workflow de Search. Update Record é projetado para correspondência única. Se mais de um registro for retornado na pesquisa, somente o primeiro registro recuperado é atualizado.

  • Atualize os campos de um registro criado por um workflow Custom Create ou Create Padrão.

  • Atualize os campos padrão e Personalizados.

Cada workflow Update Record pode atualizar somente um registro. Para atualizar mais que um registro, configure mais que um workflow Update Record.

  1. Em Studio, abra o script no qual você deseja configurar o workflow Atualizar Registro.

  2. Adicione uma SNIPPET ação após ONANSWER ou ONASSIGNMENT.

  3. Duplo clique na ação SNIPPET no canvas do script.

  4. Copie cada uma das seguintes linhas de código e cole-as na guia Visualização em texto da janela editor.

    
    ASSIGN recordId = workflowResultSet.result[1].records[1].id
    
    DYNAMIC updatePayload
    updatePayload.entityId = [recordId]
    updatePayload.entity = "[entity API]"
    
    DYNAMIC fields
    fields[1].key = "[FieldName]"
    fields[1].value = "[Field value]"
    
    fields[2].key = "[FieldName]"
    fields[2].value = "[Field value]"				
    
    fields[3].key = "[FieldName]"
    fields[3].value = "[Field value]"
    
    updatePayload.fields = fields
    
    DYNAMIC updateInput
    updateInput.workflowInput = updatePayload
    ASSIGN updateInputJson = "{updateInput.asjson()}"
    		
  5. Altere o valor do atributo updatePayload.entityId para o ID do registro que você deseja atualizar. Por exemplo, updatePayload.entityId = "123456-7891011-12131415".

    Você pode recuperar esse ID de registro a partir dos resultados do workflow de pesquisa que aparecem no cartão de cliente em Agent Workspace (Agent).

  6. Altere o valor do atributo updatePayload.entity para o nome de API do registro que você deseja atualizar. Por exemplo, updatePayload.entity = "account". Diferencia maiúsculas de minúsculas. Você pode usar o nome da API de um registro padrão ou personalizado.

    Para localizar o nome da API do registro, abra Salesforce e navegue até Setup Icon of gray gear with a lightning bolt in the center > Object Manager. Clique no nome do registro. Na página Detalhes que é aberta, localize o API Name.

  7. Altere o valor dos atributos fields.key para os campos que deseja atualizar. Por exemplo, fields[1].key = "SuppliedPhone".
  8. Altere o valor dos atributos de fields.value para os novos valores dos campos. Esses podem ser codificados diretamente, variáveis ou uma combinação deles. Por exemplo, fields[1].value = "{ANI}".
  9. Salve o seu script.

  10. Você pode testar seu script simulando uma interação no Studio.

Fixar registros

Você pode fixar um registro na seção Interação Atual do cartão do cliente. Quando um registro é fixado, ele é vinculado icon of a check mark in a green box. para memorialização de dados e informações de linha do tempo por padrão. Isso significa que as informações de memorialização de dados e de linha do tempo serão adicionadas ao registro Salesforce quando a interação for concluída. Se o agente não quiser que as informações sejam mapeadas, ele poderá desvincular o registro.

  1. Abra a ação Snippet for Create Workflow SNIPPET em seu script.

  2. Na carga útil do fluxo de trabalho, copie esta linha de código e cole-a antes de DYNAMIC create[RecordType]Payload:

    						
    createPayload.pinnedRecord = "true"					
    		
  3. Make sure that createPayload matches the earlier lines in your workflow. For example, if you're using the standard Create Case workflow, this line should be createCase.pinnedRecord = "true".

  4. Salve o seu script.

Configurar registros para Screen Pop

Você pode configurar registros para que apareçam automaticamente como pop-ups de tela em Salesforce. Isso é feito editando a carga útil do Workflow.

Pesquisar em Fluxos de trabalho

By padrão, os registros de correspondência únicaClosed Ocorre quando um workflow de pesquisa retorna somente um registro. aparecem como Tela pops. Você pode alterar isso definindo o atributo screenPop como false.

Múltiplos registros de correspondência não aparecem como Tela pops, mesmo se você definir o atributo screenPop como true.

  1. Abra a ação SNIPPET do workflow no seu script Studio.

  2. Na carga útil do fluxo de trabalho, copie esta linha de código e cole-a antes de ASSIGN searchJson = "{searchInput.asjson()}":

    						
    searchPayload.screenPop = "[true or false]"				
    		
  3. Configure o code colado.

    1. Verifique se searchPayload corresponde às linhas anteriores no seu workflow. Por exemplo, no workflow Custom Search, esta linha deve ser payload.screenPop. No workflow Search for ANI, ela deve ser searchInput.workflowInput.screenPop.

    2. Alterar o valor do atributo screenPop:

      • Defina-o como true para mostrar o registro como uma tela pop.

      • Defina-o como false para não mostrá-lo.

  4. Salve o seu script.

Em Criar Fluxos de trabalho

Por padrão, os registros criados não aparecem como Tela pops. Você pode alterar isso definindo o atributo screenPop como true.

  1. Abra a ação SNIPPET do workflow no script Studio.

  2. Na carga útil do fluxo de trabalho, copie esta linha de código e cole-a antes de DYNAMIC create[RecordName]Payload:

    						
    createPayload.screenPop = "[true or false]"				
    		
  3. Configure o code colado.

    1. Certifique-se de que createPayload corresponda às linhas anteriores do seu workflow. Por exemplo, no workflow padrão Create Case, esta linha deve ser createCase.screenPop.

    2. Alterar o valor do atributo screenPop:

      • Defina-o como true para mostrar o registro como uma tela pop.

      • Defina-o como false para não mostrá-lo.

  4. Salve o seu script.

Configurar o armazenamento em cache de Workflow

Você pode controlar se os resultados do workflow de pesquisa e Criação são armazenados em cache. Isso é feito editando a carga útil do workflow. Quando os resultados são armazenados em cache, eles aparecem no cartão do cliente no aplicativo do agente.

Pesquisar Fluxos de trabalho

Por padrão, os resultados de workflow de pesquisa ficam em cache. Você pode alterar isso definindo o atributo cacheResponse como false. Os registros retornados não aparecerão no aplicativo do agente.

  1. Abra a ação SNIPPET do workflow em seu script Studio.

  2. Na carga útil do fluxo de trabalho, copie esta linha de código e cole-a antes de ASSIGN searchJson = "{searchInput.asjson()}":

    						
    searchPayload.cacheResponse = "[true or false]"				
    		
  3. Configure o code colado.

    1. Certifique-se de que searchPayload corresponda às linhas anteriores do seu workflow. Por exemplo, no Custom Search workflow, esta linha deve ser payload.cacheResponse.

    2. Alterar o valor do atributo cacheResponse:

      • Defina-o como true para armazenar em cache os resultados do workflow.

      • Defina como false para não armazená-los em cache.

  4. Salve seu script.

Em Criar Fluxos de trabalho

Por padrão, os resultados de Create Workflow são armazenados em cache. Você pode alterar isso definindo o atributo cacheResponse como false. Os registros criados não aparecerão no aplicativo do agente.

  1. Abra a ação SNIPPET do workflow em seu script.

  2. Na carga útil do fluxo de trabalho, copie esta linha de código e cole-a antes de DYNAMIC create[RecordName]Payload:

    						
    createPayload.cacheResponse = "[true or false]"				
    		
  3. Configure o code colado.

    1. Verifique se createPayload corresponde às linhas anteriores no seu workflow. Por exemplo, no workflow padrão Criar Caso, esta linha deve ser createCase.cacheResponse.

    2. Alterar o valor do atributo cacheResponse:

      • Defina como true para armazenar em cache os resultados do workflow.

      • Defina como false para não armazená-los em cache.

  4. Salve o seu script.