Instruções de tomada de decisão

As informações desta página de ajuda se aplicam tanto a Studio quanto a Desktop Studio.

Você pode fazer com o que seu script selecione uma tarefa para desempenhar com base nas condições que especificar Usando uma instrução de tomada de decisão, é possível criar o script para lidar com várias possibilidades e resultados diferentes. Isso permite que você controle o fluxo linear do que acontece em seu script.

As palavras-chave para essas instruções são:

Instruções de tomada de decisão sempre exigem blocos de código condicionais. Blocos são delimitados por chaves ( { } ). Os blocos de código para instruções SELECT e SWITCH usam duas palavras-chave adicionais:

  • CASE: define uma de um conjunto de possíveis instruções a ser executada.
  • DEFAULT: Define o CASE padrão. Esta é a instrução que é executada se nenhuma das outras instruções CASE puder ser executada.

A discussão de cada tipo de instrução inclui um resumo de sintaxe. Esses resumos usam determinadas convenções para indicar as partes da instrução e se cada parte é obrigatória ou opcional.

IF e IF... ELSE instruções

Descrição: Avalia uma expressão e toma um ramal com base nos resultados da avaliação.

Sintaxe: IF <expression> <{ ... }> [ ELSE { ... } ]

Studio Ação: If

Detalhes: IF instruções avaliam um <expression>. Dependendo de como a expressão é avaliada, o script executa o código no primeiro conjunto de chaves { ... }. A expressão deve ser avaliada como true ou o script não executará o código.

Você pode incluir a instrução ELSE se quiser especificar o que o script faz quando a expressão é avaliada como falsa. ELSE é opcional. Use-a quando houver duas ações possíveis e quando quiser que o script escolha entre elas. Use IF sozinha quando houver apenas uma ação possível e quando quiser que o script a execute apenas quando a condição especificada (<expression>) for atendida.

Use um operador booleanoClosed Um tipo de dados que tem dois valores possíveis: verdadeiro e falso. na expressão <expression> que faz parte da instrução IF. Você deve usar uma expressão que é avaliada ou como true ou como false. Por exemplo, x=5 é uma expressão válida pois o valor da variável x ou será igual a 5 ou não será.

Studio não oferece suporte a mais de uma instrução ELSE em um IF. No entanto, você pode inserir instruções IF:


IF A > B {
// Do something
}
ELSE {
	IF A = B {
	// Do something else
	}
	ELSE {
	// Do this
	}
}

Exemplo

IF TEST = 1
   {
      ASSIGN contactID = "123456780"
      ASSIGN customerName = "XYZ International"
      ASSIGN CBWindowStart = #"{date} 8:00 AM"
      ASSIGN CBWindowEnd = #"{date} 4:30 PM"
   }

//String Comparison

IF customerName = "ABC Corporation"
   {
      ASSIGN contractLevel = "Gold"
   }
   ELSE
      {
         ASSIGN contractLevel = "Silver"
      }

//Numeric Comparision

IF contactID % 10 = 0
   {
      ASSIGN logCall = 1
   }
   ELSE
      {
         ASSIGN logCall = 0
      }

//DateTime Comparison

ASSIGN myTime = #"{time}"

IF myTime >= CBWindowStart && myTime  <= CBWindowEnd
   {
      ASSIGN offerCallback = "True"
   }
   ELSE
      {
         ASSIGN offerCallback = "False"
      }

SELECT instruções

Descrição: Executa um conjunto de comandos com base na primeira expressão a ser avaliada como true.

Sintaxe: SELECT <{ CASE <expression> [{ ... }] [CASE <expression> <{ ... }>] [CASE ...] [DEFAULT <{ ... }>] }>

Detalhes: Em uma instrução SELECT, o script avalia cada CASE <expression> começando pela parte superior e descendo até encontrar o primeiro que seja avaliado como verdadeiro. Para a primeira CASE <expression> avaliada como true, SELECT executa o código dentro das chaves [{ ... }] daquela CASE <expression>.

Se nenhuma CASE <expression> for avaliada como true, o script executará o código opcional DEFAULT { ... }.

Pelo menos uma instrução CASE é esperada. Se incluída, a instrução DEFAULT { ... } deve ser a última cláusula na lista de instruções CASE.

Por exemplo:

SELECT
{
	CASE name="Odin" { agentid = 123 }
	CASE name="Frigg" { agentid = 345 }
	CASE name.length = 0
	 {
	   ASSIGN agentid = -1
	   ASSIGN error = "Invalid name"
	 }
	DEFAULT { ASSIGN agentid = 999 }
} 

SWITCH instruções

Descrição: Avalia a variável especificada e executa a ação definida pelo CASE correspondente.

Sintaxe: SWITCH <var> <{CASE <literal> [{ ... }] [CASE <literal> [{ ... }]] [CASE ...] [DEFAULT [{ ... }]] }>

Detalhes: Uma instrução SWITCH compara o valor de uma variável <var> ao valor literal de cada CASE <literal>. Quando uma correspondência CASE é encontrada, SWITCH é executado e se ramifica para o código entre chaves { ... } associado à correspondência CASE <literal>.

Se nenhum CASE <literal> corresponder a <var>, o código opcional DEFAULT { ...} será executado. DEFAULT deve ser a última cláusula nas instruções inseridas na instrução SWITCH.

SWITCH pode apenas avaliar uma variável. Não é possível avaliar uma expressão. Se usar uma expressão, seu script não funcionará.

Pelo menos um CASE é esperado. Todas as instruções CASE devem ter o mesmo tipo de <literal>. O primeiro CASE determina o tipo para as instruções restantes CASE. Se alguma instrução CASE tiver um tipo diferente do primeiro CASE, ocorrerá um erro de compilador. Os seguintes são todos os tipos literais válidos:

  • CASE "john"
  • CASE 512
  • CASE #"5/15/2050"
  • CASE #"6/1/2050 7:00am"
  • CASE #"7am"

Por exemplo:

IF TEST = 1
{
  ASSIGN MyDate = "07/03/2023" //This date falls on a Monday
}
ASSIGN MyDow = MyDate.asdatedow
SWITCH MyDow
{
  CASE 0   { ASSIGN NewToday = "Sunday"  }
  CASE 1   { ASSIGN NewToday = "Monday"  }
  CASE 2   { ASSIGN NewToday = "Tuesday" }
  CASE 3   { ASSIGN NewToday = "Wednesday" }
  CASE 4   { ASSIGN NewToday = "Thursday" }
  CASE 5   { ASSIGN NewToday = "Friday"  }
  CASE 6   { ASSIGN NewToday = "Saturday"   }
}

Se mais que um CASE usar o mesmo código { ... }, não é necessário incluir um bloco de código após cada um. Em vez disso, liste as CASE palavras-chave uma após a outra, com o código após o último CASE que usa esse código. Isso é chamado de fall-through de caso. Isso é permitido desde que haja um case que tem um bloco de código para o SWITCH encontrar. O exemplo a seguir mostra uma caída de case. Para CASEs 1, 2 e 3, a saída é o valor hi. Nos CASEs 5 e 6, a saída é bye.

SWITCH x
{
	CASE 1
	CASE 2
	CASE 3 { TRACE "hi" }
	CASE 5
	CASE 6 { TRACE "bye" }
}

Caso de uso: SWITCH permite que você tenha resultados específicos dependendo do que a variável especificada contém. Por exemplo, é possível fazer com que o script avalie uma variável contendo códigos de área. Você pode definir um CASE para cada código de área possível e fazer com que o script adicione um valor à variável state que corresponde ao estado ao qual o código de área está atribuído. Por exemplo:

SWITCH areaCode
{
	CASE 603 { state =  "New Hampshire" }
	CASE 614 { state =  "Ohio" }
	CASE 628 { state =  "California" }
	CASE 646 { state =  "New York" }
	CASE 667 { state =  "Maryland" }
}

CASE instruções

Descrição: define um de um conjunto de instruções possíveis para ser executado. Usado com SWITCH ou SELECT.

Sintaxe: varia; consulte SWITCH ou SELECT

Studio Ação: Case

Detalhes: CASE deve ser usado no bloco de código condicional de uma instrução SWITCH ou SELECT. Adicione uma ou mais instruções CASE para definir os possíveis blocos a serem executados pelo script. É necessário pelo menos um CASE.

Relacionado: inclui uma instrução DEFAULT para definir o caso a ser usado se nenhuma das instruções CASE especificadas for aplicável.

DEFAULT instruções

Descrição: Define o bloco CASE que é usado se nenhum dos CASEs especificados se aplicar. Usada com SWITCH e SELECT.

Sintaxe: Varia; consulte SWITCH ou SELECT

Detalhes: DEFAULT deve ser usado com blocos SWITCH ou SELECT, e deve haver pelo menos uma instrução CASE presente. DEFAULT não pode ser usado por si só. DEFAULT é sempre opcional. Ela deve ser a última cláusula na lista de instruções CASE.

ELSE instruções

Descrição: Define a instrução que o script executa se a expressão IF for avaliada como false.

Sintaxe: { ELSE ... }; consulte IF

Detalhes: ELSE é sempre opcional. Você pode incluir uma instrução ELSE se quiser especificar o que o script faz quando a expressão é avaliada como false. Use-a quando houver duas ações possíveis e quando quiser que o script escolha entre elas.